Startseite Themenstart

Summenprodukt

Die Standardfunktion Summenprodukt gehört zu den Funktionen, die zu Unrecht ein Schattendasein führen. Ich bin nicht sicher, ob es daran liegt, dass viele Anwender die darin verborgenen Möglichkeiten nicht kennen, oder ob es eine gewisse Scheu vor Matrixfunktionen ist. Auch die Excelhilfe ist bei dieser Funktion eher etwas oberflächlich. Trotzdem greife ich für die Beschreibung das Beispiel von dort auf.
Tabelle1

 ABCDEF
1Matrix 1Matrix 2 156
23427  
38667  
41953  

Formeln der Tabelle
ZelleFormel
F1=SUMMENPRODUKT(A2:B4;C2:D4)
Verstanden? Eher nicht. Sehen wir uns an, was die Funktion macht:
Tabelle1

 ABC
6628 
74842 
8527 
95997156

Formeln der Tabelle
ZelleFormel
A6=A2*C2
B6=B2*D2
A7=A3*C3
B7=B3*D3
A8=A4*C4
B8=B4*D4
A9=SUMME(A6:A8)
B9=SUMME(B6:B8)
C9=SUMME(A9:B9)
Es werden also die Werte der linken Spalte aus Matrix 1 mit der linken Spalte aus Matrix 2 multipliziert. Das geschieht auch mit den rechten Spalten. Aus den Ergebnissen wird dann eine Summe gebildet. Wow, das kann aber nicht alles sein! Nun, ist es auch nicht. Man kann in die Berechnungen sogenannte Wahrheitswerte einbauen, damit entfaltet sich die ganze Mächtigkeit der Funktion.
Als Beispiel die Mitgliederliste eines Vereins. (Die Liste ist aus Platzgründen verkürzt dargestellt.)
Tabelle1

 ABCDEFGHIJKLM
1LfdNrNameVornameGeburtsdatumAlterm / wErmäßigung Auswertung
21AndersMaria29.09.8323w  AlterWeiblichMännlichSummedavon ermäßigt
32TrujilloAna26.01.7334w  < 61341
43MorenoAntonio06.12.7531m  7-1437101
54HardyThomas14.12.5749m  151120
65BerglundChristina20.09.5848wX 16-181450
76MoosHanna13.01.8819w  19-2646101
87CiteauxFrédérique13.11.4066w  27-40139222
98SommerMartín02.03.8720mX 41-60820282
109LebihanLaurence01.07.9016m  > 6073100
1110LincolnElizabeth17.12.8323w  Summen3853917
1211AshworthVictoria24.10.4264w       
1312SimpsonPatricio02.09.6541m       

Formeln der Tabelle
ZelleFormel
J3=SUMMENPRODUKT((F$2:F$99="w")*(E$2:E$99<=6))
K3=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92<=6))
L3=J3+K3
M3=SUMMENPRODUKT((E$2:E$92<=6)*(G$2:G$92="X"))
J4=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>=7)*(E$2:E$92<=14))
K4=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>=7)*(E$2:E$92<=14))
L4=J4+K4
M4=SUMMENPRODUKT((E$2:E$92>=7)*(E$2:E$92<=14)*(G$2:G$92="X"))
J5=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92=15))
K5=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92=15))
L5=J5+K5
M5=SUMMENPRODUKT((E$2:E$92=15)*(G$2:G$92="X"))
J6=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>=16)*(E$2:E$92<=18))
K6=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>=16)*(E$2:E$92<=18))
L6=J6+K6
M6=SUMMENPRODUKT((E$2:E$92>=16)*(E$2:E$92<=18)*(G$2:G$92="X"))
J7=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>=19)*(E$2:E$92<=26))
K7=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>=19)*(E$2:E$92<=26))
L7=J7+K7
M7=SUMMENPRODUKT((E$2:E$92>=19)*(E$2:E$92<=26)*(G$2:G$92="X"))
J8=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>=27)*(E$2:E$92<=40))
K8=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>=27)*(E$2:E$92<=40))
L8=J8+K8
M8=SUMMENPRODUKT((E$2:E$92>=27)*(E$2:E$92<=40)*(G$2:G$92="X"))
J9=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>=41)*(E$2:E$92<=60))
K9=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>=41)*(E$2:E$92<=60))
L9=J9+K9
M9=SUMMENPRODUKT((E$2:E$92>=41)*(E$2:E$92<=60)*(G$2:G$92="X"))
J10=SUMMENPRODUKT((F$2:F$92="w")*(E$2:E$92>60))
K10=SUMMENPRODUKT((F$2:F$92="m")*(E$2:E$92>60))
L10=J10+K10
M10=SUMMENPRODUKT((E$2:E$92>=60)*(G$2:G$92="X"))
J11=SUMME(J3:J10)
K11=SUMME(K3:K10)
L11=SUMME(L3:L10)
M11=SUMME(M3:M10)
Es wurde mit einer Formel, die je nach gewünschten Ergebnis modifiziert ist, eine Auswertung nach Alter, differenziert nach Geschlecht durchgeführt. Auch die Anzahl der Mitglieder, die einen ermäßigten Beitrag bezahlen, wurde erfasst.